COMMENT ⊗   VALID 00003 PAGES
C REC  PAGE   DESCRIPTION
C00001 00001
C00002 00002	if crs=0: fntmode chardisplay pixels=3.6 maxht 16.8*pixels+10
C00004 00003	charcode 0 call uca(4.0).
C00008 ENDMK
C⊗;
if crs=0: fntmode; chardisplay; pixels=3.6; maxht 16.8*pixels+10;
else: crsmode; pixels=5333*.013837; fi;
tfxmode;
s=2*pixels/36; blacker=1.2; extra=3*pixels/36;
eps=.000314159; % small positive number
ucs=1.7;

subroutine uca(var pts):
new rh,re,ru,rw,rwix,cf,h,e,w0,w9,r,u;
rh=25/36*pts; re=9/36*pts; ru=(1.5pts+5)/36;
rw=(.4pts+5)/36; rwix=(3.6pts+2)/36;
cf.rh=pixels.rh-1;
h=round cf.rh; e=round cf.re;
w0=.5+round(pixels.rw+blacker);
w9=.5+round(pixels.rwix+blacker);
r=13u;
charht rh;
13u = 13.ru.pixels-1; charwd 13ru;
hpen;
lft0x1=round(1.5u+s.nrand); bot0y1=round s.nrand;
rt9x4=round(r-1.5u+s.nrand); bot9y4=round s.nrand;
x3-x1=x4-x2+s.nrand;
rt9x2=rt0x3;
top0y3=top9y2=h+s.nrand+2extra;
w9 draw 2..4; % right diagonal stroke
y5=e+s.nrand; y6=e+s.nrand;
x5-1=(y5-y1)/(y3-y1)[x1,x3];
x6+1=(y6-y4)/(y2-y4)[x4,x2];
w0 draw 5..6; % bar line
lers; w9 draw 3..5; % erase excess at left
hpen; w0 draw 3..1; % left diagonal stroke
lft0x7=lft0x1-.5ucs.u-eps; rt0x8=rt0x1+ucs.u+eps;
lft0x9=lft9x4-ucs.u-eps; rt0x10=rt9x4+.5ucs.u+eps;
y7=y1+.2s.nrand; y8=y1+.2s.nrand;
y9=y4+.2s.nrand; y10=y4+.2s.nrand;
w0 draw 7..8; draw 9..10; % serifs
if crs: if pts>16: crsbreak 1/2 e; fi; else: chardw round(r+1); fi.
charcode 0; call uca(4.0).
charcode 1; call uca(4.1).
charcode 65; call uca(10.5).
charcode 126; call uca(16.6).
charcode 127; call uca(16.7).